Added nix-serve app and package

1 files changed, 61 insertions, 0 deletions

diff --git a/modules/pkgs/nix-serve/nix-serve.psgi b/modules/pkgs/nix-serve/nix-serve.psgi
new file mode 100644
index 0000000..ac4071b
--- /dev/null
+++ b/modules/pkgs/nix-serve/nix-serve.psgi
@@ -0,0 +1,61 @@
+# This is nix-serve (https://github.com/edolstra/nix-serve) using pxz instead of bzip2
+use MIME::Base64;
+use Nix::Config;
+use Nix::Manifest;
+use Nix::Store;
+use Nix::Utils;
+use strict;
+
+sub stripPath {
+    my ($x) = @_;
+    $x =~ s/.*\///; $x
+}
+
+my $app = sub {
+    my $env = shift;
+    my $path = $env->{PATH_INFO};
+
+    if ($path eq "/nix-cache-info") {
+        return [200, ['Content-Type' => 'text/plain'], ["StoreDir: $Nix::Config::storeDir\nWantMassQuery: 1\nPriority: 30\n"]];
+    }
+
+    elsif ($path =~ "/([0-9a-z]+)\.narinfo") {
+        my $hashPart = $1;
+        my $storePath = queryPathFromHashPart($hashPart);
+        return [404, ['Content-Type' => 'text/plain'], ["No such path.\n"]] unless $storePath;
+        my ($deriver, $narHash, $time, $narSize, $refs) = queryPathInfo($storePath, 1) or die;
+        my $res =
+            "StorePath: $storePath\n" .
+            "URL: nar/$hashPart.nar.xz\n" .
+            "Compression: xz\n" .
+            "NarHash: $narHash\n" .
+            "NarSize: $narSize\n";
+        $res .= "References: " . join(" ", map { stripPath($_) } @$refs) . "\n"
+            if scalar @$refs > 0;
+        $res .= "Deriver: " . stripPath($deriver) . "\n" if defined $deriver;
+        my $secretKeyFile = $ENV{'NIX_SECRET_KEY_FILE'};
+        if (defined $secretKeyFile) {
+            my $s = readFile $secretKeyFile;
+            chomp $s;
+            my ($keyName, $secretKey) = split ":", $s;
+            die "invalid secret key file ‘$secretKeyFile’\n" unless defined $keyName && defined $secretKey;
+            my $fingerprint = fingerprintPath($storePath, $narHash, $narSize, $refs);
+            my $sig = encode_base64(signString(decode_base64($secretKey), $fingerprint), "");
+            $res .= "Sig: $keyName:$sig\n";
+        }
+        return [200, ['Content-Type' => 'text/x-nix-narinfo'], [$res]];
+    }
+
+    elsif ($path =~ "/nar/([0-9a-z]+)\.nar.xz") {
+        my $hashPart = $1;
+        my $storePath = queryPathFromHashPart($hashPart);
+        return [404, ['Content-Type' => 'text/plain'], ["No such path.\n"]] unless $storePath;
+        my $fh = new IO::Handle;
+        open $fh, "nix-store --dump '$storePath' | nice -n 19 pxz -0 |";
+        return [200, ['Content-Type' => 'application/x-xz'], $fh];
+    }
+
+    else {
+        return [404, ['Content-Type' => 'text/plain'], ["File not found.\n"]];
+    }
+}