From 27b29703a46bcde319961c2b52d38da3513a1da8 Mon Sep 17 00:00:00 2001
From: Igor Pashev <pashev.igor@gmail.com>
Date: Sun, 28 Jun 2020 17:36:49 +0200
Subject: Make location a part of API

---
 lib/Web/OpenWeatherMap/Types/Location.hs | 34 ++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)
 create mode 100644 lib/Web/OpenWeatherMap/Types/Location.hs

(limited to 'lib/Web/OpenWeatherMap/Types/Location.hs')

diff --git a/lib/Web/OpenWeatherMap/Types/Location.hs b/lib/Web/OpenWeatherMap/Types/Location.hs
new file mode 100644
index 0000000..72712ed
--- /dev/null
+++ b/lib/Web/OpenWeatherMap/Types/Location.hs
@@ -0,0 +1,34 @@
+{-# LANGUAGE FlexibleInstances #-}
+{-# LANGUAGE MultiParamTypeClasses #-}
+{-# LANGUAGE OverloadedStrings #-}
+{-# LANGUAGE ScopedTypeVariables #-}
+{-# LANGUAGE TypeFamilies #-}
+{-# LANGUAGE TypeOperators #-}
+
+module Web.OpenWeatherMap.Types.Location
+  ( Location(..)
+  ) where
+
+import Data.Proxy (Proxy(..))
+
+import Servant.API ((:>))
+import Servant.Client (Client, HasClient, clientWithRoute, hoistClientMonad)
+import Servant.Client.Core.Request (appendToQueryString)
+import Web.HttpApiData (toQueryParam)
+
+-- | Various way to specify location.
+data Location
+  = Name String -- ^ City name.
+  | Coord Double Double -- ^ Geographic coordinates: latitude and longitude.
+
+instance HasClient m api => HasClient m (Location :> api) where
+  type Client m (Location :> api) = Location -> Client m api
+  clientWithRoute pm Proxy req loc =
+    clientWithRoute pm (Proxy :: Proxy api) (addParams loc req)
+    where
+      addParams (Name q) = appendToQueryString "q" (Just $ toQueryParam q)
+      addParams (Coord lat lon) =
+        appendToQueryString "lat" (Just $ toQueryParam lat) .
+        appendToQueryString "lon" (Just $ toQueryParam lon)
+  hoistClientMonad pm _ f cl =
+    \a -> hoistClientMonad pm (Proxy :: Proxy api) f (cl a)
-- 
cgit v1.2.3