dnl Process this file with autoconf to produce a configure script.
AC_INIT(vpath.c)		dnl A distinctive file to look for in srcdir.
AC_CONFIG_HEADER(config.h)

AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_RANLIB
AC_PROG_CPP			dnl Later checks need this.
AC_AIX
AC_ISC_POSIX
AC_MINIX
AC_STDC_HEADERS
AC_MEMORY_H
AC_UNISTD_H
AC_DIR_HEADER
AC_UID_T			dnl Also does gid_t.
AC_PID_T
AC_RETSIGTYPE
AC_HAVE_HEADERS(limits.h sys/param.h fcntl.h)
AC_MINUS_C_MINUS_O

AC_SUBST(LIBOBJS)

AC_HAVE_FUNCS(getdtablesize sys_siglist _sys_siglist \
	      dup2 getcwd sigsetmask getgroups setlinebuf \
	      setreuid setregid)
AC_ALLOCA
AC_VFORK
AC_SETVBUF_REVERSED
AC_GETLOADAVG
AC_STRCOLL

dnl Look for waitpid first.
AC_COMPILE_CHECK(waitpid, [#include <sys/types.h>
#include <sys/wait.h>],
		 [return waitpid (-1, (int *) 0, WNOHANG);],
		 AC_DEFINE(HAVE_WAITPID),
		 dnl No waitpid; try wait3.
		 AC_COMPILE_CHECK(wait3, [#include <sys/wait.h>],
				  [return wait3 (0, WNOHANG, 0);],
				  AC_DEFINE(HAVE_SYS_WAIT)))

AC_USG

# The presence of the following is not meant to imply
# that make necessarily works on those systems.
AC_DYNIX_SEQ
AC_XENIX_DIR

AC_OUTPUT(Makefile glob/Makefile)

dnl Local Variables:
dnl comment-start: " dnl "
dnl comment-end: ""
dnl comment-start-skip: "\\bdnl\\b\\s *"
dnl compile-command: "make configure config.h.in"
dnl End: